Checker-capture Chess
Setup
Same as normal (FIDE) chess.
Rules
The standard rules of FIDE chess apply in general, with these differences:
- Captures by displacement cannot be made.
- Captures are made by short jumps, in any of 8 directions, and must be continued as long as possible (but you are not required to make the longest possible series of jumps).
- Captures by jumps must be made if possible, but you can select if there are multiple possibilities.
- No check/checkmate. Lose if your king is captured, also lose if you have no legal moves on your turn (stalemated).
- Castling is allowed out of check or through check. However, it is completely impossible to castle into check.
- No en-passan.
- Pawns only promote if the final position of the pawn is at the eighth row at the end of the full move.
For a simpler variation you can include these rules:
- No pawn double-step.
- No castling.
- Pawns at the eighth row do not promote immediately. If you are making a non-capturing move with a pawn starting from the eighth row, you may promote at that point, to a rook or knight or bishop or queen, and then immediately move.
There are also 2 additional variants you can play, with or without the simpler variation.
Misere:
- Win if your king is captured.
- Win if you have no legal moves on your turn (stalemated).
Semi-misere:
- Lose if your king is captured.
- Win if you have no legal moves on your turn (stalemated).
- Win if you have no pawns. (Pawns can be lost by being captured or by promoting)
Displacement:
- Displacement capture is also allowed.
- If you can jump, you still must jump instead of displacement capture.
- If jumping is not available and displacement capture is available, it is not required to make a displacement capture, you may make a normal move instead if you want to.
Notes
Here is the Zillions code for this game in case you want to see how it works, run it, or don't understand a rule and hope this will clarify it for you.
<![CDATA[(include "Z_GenImg.lib")
(define step1 ( $1 (verify empty?) add ))
(define step2 ( $1 $2 (verify empty?) add ))
(define ride ( $1 (while empty? add $1) ))
(define jumps ( $1 (verify enemy?) capture $1 (verify empty?) (add-partial jumping-move) ))
(define jumping-moves
(move-type jumping-move)
(jumps n)
(jumps ne)
(jumps e)
(jumps se)
(jumps s)
(jumps sw)
(jumps w)
(jumps nw)
)
(define step1oc ( $1 (verify enemy?) add ))
(define step1d ( $1 (verify not-friend?) add ))
(define step2d ( $1 $2 (verify not-friend?) add ))
(define rided ( $1 (while empty? add $1) (verify not-friend?) add ))
(game
(title "Checker-capture Chess (Normal)")
(players Red Cyan)
(board
(8x8board)
(vertical-symmetry Cyan)
)
(board-setup
(Red
(Pawn a2 b2 c2 d2 e2 f2 g2 h2)
(Knight b1 g1)
(Bishop c1 f1)
(Rook a1 h1)
(Queen d1)
(King e1)
)
(Cyan
(Pawn a7 b7 c7 d7 e7 f7 g7 h7)
(Knight b8 g8)
(Bishop c8 f8)
(Rook a8 h8)
(Queen d8)
(King e8)
)
)
(turn-order Red Cyan)
(loss-condition (Red Cyan) (captured King))
(loss-condition (Red Cyan) stalemated)
(move-priorities jumping-move normal-move)
(piece
(name Pawn)
(image_P)
(moves
(move-type normal-move)
(step1 n)
((verify (not-on-board? n)) (add-partial Queen Knight Rook Bishop normal-move))
(jumping-moves)
)
)
(piece
(name Knight)
(image_N)
(moves
(move-type normal-move)
(step2 n ne)
(step2 n nw)
(step2 s se)
(step2 s sw)
(step2 e ne)
(step2 e se)
(step2 w nw)
(step2 w sw)
(jumping-moves)
)
)
(piece
(name Bishop)
(image_B)
(moves
(move-type normal-move)
(ride nw)
(ride sw)
(ride se)
(ride ne)
(jumping-moves)
)
)
(piece
(name Rook)
(image_R)
(moves
(move-type normal-move)
(ride n)
(ride s)
(ride e)
(ride w)
(jumping-moves)
)
)
(piece
(name Queen)
(image_Q)
(moves
(move-type normal-move)
(ride nw)
(ride sw)
(ride se)
(ride ne)
(ride n)
(ride s)
(ride e)
(ride w)
(jumping-moves)
)
)
(piece
(name King)
(image_K)
(moves
(move-type normal-move)
(step1 nw)
(step1 sw)
(step1 se)
(step1 ne)
(step1 n)
(step1 s)
(step1 e)
(step1 w)
(jumping-moves)
)
)
)
(variant
(title "Checker-capture Chess (Misere)")
(win-condition (Red Cyan) (captured King))
(win-condition (Red Cyan) stalemated)
)
(variant
(title "Checker-capture Chess (Semi-misere)")
(loss-condition (Red Cyan) (captured King))
(win-condition (Red Cyan) stalemated)
(win-condition (Red Cyan) (pieces-remaining 0 Pawn))
)
(variant
(title "Checker-capture Chess (Including displacement capture)")
(piece
(name Pawn)
(image_P)
(moves
(move-type normal-move)
(step1 n)
(step1oc nw)
(step1oc ne)
((verify (not-on-board? n)) (add-partial Queen Knight Rook Bishop normal-move))
(jumping-moves)
)
)
(piece
(name Knight)
(image_N)
(moves
(move-type normal-move)
(step2d n ne)
(step2d n nw)
(step2d s se)
(step2d s sw)
(step2d e ne)
(step2d e se)
(step2d w nw)
(step2d w sw)
(jumping-moves)
)
)
(piece
(name Bishop)
(image_B)
(moves
(move-type normal-move)
(rided nw)
(rided sw)
(rided se)
(rided ne)
(jumping-moves)
)
)
(piece
(name Rook)
(image_R)
(moves
(move-type normal-move)
(rided n)
(rided s)
(rided e)
(rided w)
(jumping-moves)
)
)
(piece
(name Queen)
(image_Q)
(moves
(move-type normal-move)
(rided nw)
(rided sw)
(rided se)
(rided ne)
(rided n)
(rided s)
(rided e)
(rided w)
(jumping-moves)
)
)
(piece
(name King)
(image_K)
(moves
(move-type normal-move)
(step1d nw)
(step1d sw)
(step1d se)
(step1d ne)
(step1d n)
(step1d s)
(step1d e)
(step1d w)
(jumping-moves)
)
)
)]]>
This 'user submitted' page is a collaboration between the posting user and the Chess Variant Pages. Registered contributors to the Chess Variant Pages have the ability to post their own works, subject to review and editing by the Chess Variant Pages Editorial Staff.
By (zzo38) A. Black.
Web page created: 2008-12-28. Web page last updated: 2009-01-10